Use Constraint Streams in OptaWeb Vehicle Routing

// Hard constraints

rule "vehicleCapacity"
    when
        $vehicle : PlanningVehicle($capacity : capacity)
        accumulate(
                    PlanningVisit(
                        vehicle == $vehicle,
                        $demand : demand);
                    $demandTotal : sum($demand);
                    $demandTotal > $capacity
                )
    then
        scoreHolder.addHardConstraintMatch(kcontext, $capacity - $demandTotal);
end

// Soft constraints

rule "distanceToPreviousStandstill"
    when
        $visit : PlanningVisit(previousStandstill != null, $distanceFromPreviousStandstill : distanceFromPreviousStandstill)
    then
        scoreHolder.addSoftConstraintMatch(kcontext, - $distanceFromPreviousStandstill);
end

rule "distanceFromLastCustomerToDepot"
    when
        $visit : PlanningVisit(previousStandstill != null)
        not PlanningVisit(previousStandstill == $visit)
    then
        PlanningVehicle vehicle = $visit.getVehicle();
        scoreHolder.addSoftConstraintMatch(kcontext, - $visit.getDistanceTo(vehicle));
end